XSL to check for tag existence and add in doesn't exist along with namespace

[shwetank sharma]

Hi,
I need to check for existence of a tag in request, till this point its done, after that if that tag doesn't exist i need to add the same.

My XSLT looks like <?xml version="1.0" encoding="UTF-8"?> <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:fo="http://www.w3.org/1999/XSL/Format"> <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/> <xsl:template match="/"> <xsl:choose> <xsl:when test="/*/*/*/*/*[local-name()='MyTag']"> <xsl:value-of select="/*/*/*/*/*[local-name()='MyTag']" /> </xsl:when> <xsl:otherwise> <!-- This part need to be corrected and helped --> <xsl:element name="{local-name()}"> </xsl:element> </xsl:otherwise> </xsl:choose> </xsl:template> </xsl:stylesheet>

My XML look like
<soapenv:Envelope xmlns:soapenv="http://schemas.xmlsoap.org/soap/envelope/" xmlns:pat="http://my.com"> <soapenv:Header/> <soapenv:Body> <pat:Request> <pat:header> <pat:login>admin</pat:login> <pat:password>admin</pat:password> <!-- Below tag is being looked upon --> <pat:MyTag>111</pat:MyTag> </pat:header> </pat:Request> </soapenv:Body> </soapenv:Envelope>

Any sort of help is highly appreciated.

[g tsuji]

[0] I don't think abstracting the criteria to being the existence of a tag of local-name 'MyTag" at the level of depth to the 5th is a realistic abstraction. It can be done (see [2]), but it would give most probably wrong outcome than the right in most case except a very narrow scope of the incoming xml document.

[1] I advance that a more realistic criterion would be starting from knowing the specific namespace uri (http://my.com) and that the container node having the local-name header in that namespace. From thereon, check if there exists the tag MyTag of the same namespace as a child. If it does not exist, add that one to it. In that case, this is how the xsl document looks like. (prefix x tries to highlight the arbitrariness of it as long as it points to the right namespace.)

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:x="http://my.com"
>
<xsl:output method="xml" encoding="utf-8" indent="yes" />
<xsl:template match="comment()|processing-instruction()|node()|@*|text()">
    <xsl:copy>
        <xsl:apply-templates select="comment()|processing-instruction()|node()|@*|text()" />
    </xsl:copy>
</xsl:template>
<xsl:template match="x:header">
    <xsl:copy>
        <xsl:apply-templates select="comment()|processing-instruction()|node()|@*|text()" />
        <xsl:if  test="not(x:myTag)">
            <xsl:element name="x:myTag">
                <xsl:value-of select="'your desired value'" />
            </xsl:element>
        </xsl:if>
    </xsl:copy>
</xsl:template>
</xsl:stylesheet>

[2] If you insist on your set of criteria, it would look like this. (But again, it would be more self-misleading than really helpful, despite it contains plenty of illustrative and useful elements of construction.)

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" encoding="utf-8" indent="yes" />
<xsl:template match="comment()|processing-instruction()|node()|@*|text()">
    <xsl:copy>
        <xsl:apply-templates select="comment()|processing-instruction()|node()|@*|text()" />
    </xsl:copy>
</xsl:template>
<xsl:template match="node()[count(ancestor::*)=3]">
    <xsl:copy>
        <xsl:apply-templates select="comment()|processing-instruction()|node()|@*|text()" />
        <xsl:if  test="not(*[local-name()='myTag'])">
            <xsl:variable name="ns"><xsl:value-of select="namespace-uri()" /></xsl:variable>
            <xsl:element name="x:myTag" namespace="{$ns}">
                <xsl:value-of select="'your desired value'" />
            </xsl:element>
        </xsl:if>
    </xsl:copy>
</xsl:template>
</xsl:stylesheet>